Android Studio Bumblebeeの新規プロジェクトにJava版のRealmを追加する

だいぶ書き方が変わっていて戸惑いましたが、より簡潔になりました。Realmに無関係な行も含まれていますが、こんな感じになりました。ちゃんとマニュアル読めよ俺。

目次

build.gradle (:app)

Realmはkaptが必要です。

plugins {
    id 'com.android.application'

    id 'org.jetbrains.kotlin.android'
    id 'org.jetbrains.kotlin.kapt'
    id 'org.jetbrains.kotlin.plugin.serialization'

    id 'com.google.android.libraries.mapsplatform.secrets-gradle-plugin'
    id 'realm-android'
}

build.gradle

ここでバージョンを指定します。変数にしたい場合は、gradle.propertiesにて設定したものが使えます。

plugins {
    id 'com.android.application' version '7.1.0' apply false

    id 'org.jetbrains.kotlin.android' version '1.6.10' apply false
    id 'org.jetbrains.kotlin.kapt' version '1.6.10' apply false
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.6.10' apply false

    id 'com.google.android.libraries.mapsplatform.secrets-gradle-plugin' version '2.0.0' apply false
}

settings.gradle

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }

    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == 'realm-android') {
                useModule('io.realm:realm-gradle-plugin:10.10.1')
            }
        }
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)

    repositories {
        google()
        mavenCentral()
        maven { url 'https://jitpack.io' }
    }
}